Como Buscar Archivos con Código

El siguiente código me ha parecido útil para varias cosas, si lo modificamos un poco puede servirnos para enlistar archivos de imagen y crear una galería, también puede servirnos cuando queremos evitarnos la fatiga de crear hipervínculos con archivos y así con un solo botón, buscar y abrir el archivo indicado, o también si tenemos una lista de facturas pero que se encuentran ordenadas en carpetas por año, mes y cliente, y se necesita saber la ubicación de cada factura de la lista, y así hay muchas otras cosas en que nos pudiera servir.
El código utiliza 4 Apis para realizar la búsqueda y obtener los datos de los archivos y carpetas que se van encontrando

  • FindFirstFile encuentra el primer archivo o carpeta que coincide con el nombre buscado
  • FindNextFile encuentre el siguiente archivo o carpeta que coincide con el nombre buscado partiendo del ultimo archivo o carpeta encontrada
  • GetFileAttributes obtiene información de un archivo o carpeta como por ejemplo si es un archivo oculto, o si es una carpeta o un archivo etc.
  • FindClose termina la búsqueda de cualquiera de las dos Apis anteriores

La lógica es simple, se comienza buscando en una carpeta inicial, si no se encuentra el archivo en la carpeta inicial se enlistan las subcarpetas de la carpeta inicial y se repite el proceso con cada subcarpeta hasta encontrar el archivo, si no se encuentra el archivo se devuelve empty.

Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long

Const MAX_PATH = 260
Const MAXDWORD = &HFFFF
Const INVALID_HANDLE_VALUE = -1
Const FILE_ATTRIBUTE_ARCHIVE = &H20
Const FILE_ATTRIBUTE_DIRECTORY = &H10
Const FILE_ATTRIBUTE_HIDDEN = &H2
Const FILE_ATTRIBUTE_NORMAL = &H80
Const FILE_ATTRIBUTE_READONLY = &H1
Const FILE_ATTRIBUTE_SYSTEM = &H4
Const FILE_ATTRIBUTE_TEMPORARY = &H100

Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * MAX_PATH
    cAlternate As String * 14
End Type
Function StripNulls(OriginalStr As String) As String
    If (InStr(OriginalStr, Chr(0)) > 0) Then
        OriginalStr = Left(OriginalStr, InStr(OriginalStr, Chr(0)) - 1)
    End If
    StripNulls = OriginalStr
End Function

Function FindFilesAPI(path As String, SearchStr As String)
    Dim FileName As String 'Archivo a buscar
    Dim DirCount As Integer 'Numero de subcarpetas
    Dim DirName As String 'Nombe de subcarpeta
    Dim dirNames() As String 'Arreglo de subcarpetas
    Dim nDir As Integer 'Numero de subcarpetas en la carpeta
    Dim i As Integer
    Dim hSearch As Long 
    Dim WFD As WIN32_FIND_DATA
    Dim Cont As Integer
    If Right(path, 1) <> "\" Then path = path & "\"
    'Busqueda del archivo en carpeta actual
    hSearch = FindFirstFile(path & SearchStr, WFD)
    Cont = True
    If hSearch <> INVALID_HANDLE_VALUE Then
        While Cont And FindFilesAPI = Empty
            FileName = StripNulls(WFD.cFileName)
            If (FileName <> ".") And (FileName <> "..") Then
                FindFilesAPI = path & FileName
            End If
            Cont = FindNextFile(hSearch, WFD)
        Wend
        Cont = FindClose(hSearch)
    End If
    If FindFilesAPI = Empty Then
        'Busqueda de las subcarpetas de la carpeta actual
        nDir = 0
        ReDim dirNames(nDir)
        Cont = True
        hSearch = FindFirstFile(path & "*", WFD)
        If hSearch <> INVALID_HANDLE_VALUE Then
            Do While Cont
            DirName = StripNulls(WFD.cFileName)
            If (DirName <> ".") And (DirName <> "..") Then
                If GetFileAttributes(path & DirName) And FILE_ATTRIBUTE_DIRECTORY Then
                    dirNames(nDir) = DirName
                    DirCount = DirCount + 1
                    nDir = nDir + 1
                    ReDim Preserve dirNames(nDir)
                End If
            End If
            Cont = FindNextFile(hSearch, WFD) 'Get next subdirectory.
            Loop
            Cont = FindClose(hSearch)
        End If
        'Si hay subcarpetas realizar la busqueda en cada subcarpeta
        If nDir > 0 Then
            For i = 0 To nDir - 1
                FindFilesAPI = FindFilesAPI(path & dirNames(i) & "\", SearchStr)
                If FindFilesAPI <> Empty Then Exit For
            Next i
        End If
    End If
End Function


Para usar el código se debe colocar en un módulo y se llama de la siguiente forma

Dim Archivo as String
Archivo=FindFilesAPI("C:\MyFolder","file.txt")
If Archivo<>Empty Then
	MsgBox "el archivo file.txt se encuentra en " & Archivo
End If

Anuncios

Responder

Introduce tus datos o haz clic en un icono para iniciar sesión:

Logo de WordPress.com

Estás comentando usando tu cuenta de WordPress.com. Cerrar sesión /  Cambiar )

Google photo

Estás comentando usando tu cuenta de Google. Cerrar sesión /  Cambiar )

Imagen de Twitter

Estás comentando usando tu cuenta de Twitter. Cerrar sesión /  Cambiar )

Foto de Facebook

Estás comentando usando tu cuenta de Facebook. Cerrar sesión /  Cambiar )

Conectando a %s